home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / demo1007.cir < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.0 KB  |  123 lines
  1. LTC LT1007 MACROMODEL DEMO: OUTPUT = V(55)
  2. *
  3. *                           Walt Jung
  4. *            LT1007 transient response demo test circuit
  5. *                   original edit 12/14/89
  6. *                      updated 06/28/90
  7. *
  8. * This circuit is an example of one which is deceptively simple,
  9. * yet it readily demonstrates the performance of the LT1007 op
  10. * amp macromodel.  This model uses phase/frequency extensions to
  11. * the basic Boyle type macromodel architecture.
  12. *
  13. * The test circuit is a simple voltage follower operating from 
  14. * +/-15V power supplies, tested for transient response, for 5
  15. * microseconds.  As such, this test reveals a lot of valuable
  16. * information on how the model converges, how fast it performs the
  17. * simulation, and finally, the relative comparison of the pulse
  18. * response with that of the data sheet (ref p 2-63, lower left, LTC
  19. * 1990 data book).
  20. *
  21. * In this demo, the Probe CMD file supplied calls up display parameters
  22. * which show the transient response over the 5 microsecond
  23. * interval.  You can modify this command file by subsituting other
  24. * models, for relative performance comparisions.  Further comments
  25. * are contained in LTC App Note # 41 (1 800 637-5545).
  26. *
  27. .OPT ACCT LIST NODE OPTS NOPAGE LIMPTS=1000
  28. .TRAN 0.01US 5US
  29. VIN 2 0 PULSE (-0.05 0.05 1.5US .01US .01US 2.0US 5US)
  30. .PROBE 
  31. .OP
  32. *
  33. VCC    52    0 +15V
  34. VEE    53    0 -15V
  35. R1     2    50 1
  36. R2     51   55 1
  37. C1     0    55 15PF
  38. *     (+) (-)  V+  V-  OUT
  39. XU1    50  51  52  53  55  LT1007
  40. *
  41. .SUBCKT LT1007 3 2 7 4 6
  42. RC1 7 80 6.6315E+02 
  43. RC2 7 90 6.6315E+02
  44. Q1 80 2 10 QM1
  45. Q2 90 3 11 QM2
  46. C1 80 91 200E-12
  47. RXC1 91 90 50
  48. CXC1 91 90 500E-12
  49. C2 8 98 4.000E-12
  50. RXC2 8 98 4.00K
  51. CXC2 1 98 27.000E-12
  52. CIN 3 2 5E-12
  53. DDM1 2 104 DM2
  54. DDM3 104 3 DM2
  55. DDM2 3 105 DM2
  56. DDM4 105 2 DM2
  57. RE1 10 12 -2.6233E+01
  58. RE2 11 12 -2.6233E+01
  59. IEE 12 4 7.5030E-05
  60. RE 12 0 2.666E+06
  61. CE 12 0 1.579E-12
  62. GCM 0 8 12 0 7.558E-10
  63. GA 8 0 80 90 1.5080E-03
  64. R2 8 0 1.000E+05
  65. GB 1 0 8 0 1.9176E+03
  66. RO2 1 0 6.900E+01
  67. RS 1 6 1
  68. ECL 18 0 1 6 2.828E+01
  69. GCL 0 8 20 0 1
  70. RCL 20 0 1E3
  71. D1 18 20 DM1
  72. D2 20 18 DM1
  73. D3A 131 70 DM3
  74. D3B 13 131 DM3
  75. GPL 0 8 70 7 1
  76. VC 13 6 3.0909
  77. RPLA 7 70 1E4
  78. RPLB 7 131 1E5
  79. D4A 60 141 DM3
  80. D4B 141 14 DM3
  81. GNL 0 8 60 4 1
  82. VE 6 14 3.0909
  83. RNLA 60 4 1E4
  84. RNLB 141 4 1E5
  85. IP 7 4 2.625E-03
  86. DSUB 4 7 DM2 
  87. .MODEL QM1 NPN (IS=8.0000E-16 BF=1.7857E+03)
  88. .MODEL QM2 NPN (IS=8.0062E-16 BF=4.1667E+03)
  89. .MODEL DM1 D (IS=1.000E-19)
  90. .MODEL DM2 D (IS=8.000E-16)
  91. .MODEL DM3 D (IS=1.000E-20)
  92. .ENDS LT1007
  93. **
  94. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1990
  95. *                       All rights reserved.
  96. * 
  97. *   Linear Technology Corporation hereby grants the users of this
  98. * macromodel a non-exclusive, nontransferrable license to use this
  99. *            macromodel under the following conditions:
  100. * 
  101. * The user agrees that this macromodel is licensed from Linear
  102. * Technology and agrees that the macromodel may be used, loaned,
  103. * given away or included in other model libraries as long as this
  104. * notice and the model in its entirety and unchanged is included.
  105. * No right to make derivative works or modifications to the
  106. * macromodel is granted hereby.  All such rights are reserved.
  107. * 
  108. * This model is provided as is.  Linear Technology makes no
  109. * warranty, either expressed or implied about the suitability or
  110. * fitness of this model for any particular purpose.  In no event
  111. * will Linear Technology be liable for special, collateral,
  112. * incidental or consequential damages in connection with or arising
  113. * out of the use of this macromodel.  It should be remembered that
  114. * models are a simplification of the actual circuit.
  115. * 
  116. * Linear Technology reserves the right to change these macromodels
  117. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  118. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  119. * datasheets on the actual amplifiers or the latest macromodels.
  120. * 
  121. * ----------------------------------------------------------------------- *
  122. .END
  123.